404

[ Avaa Bypassed ]




Upload:

Command:

botdev@52.14.3.26: ~ $
# id.awk --- implement id in awk
#
# Requires user and group library functions
#
# Arnold Robbins, arnold@skeeve.com, Public Domain
# May 1993
# Revised February 1996
# Revised May 2014
# Revised September 2014

# output is:
# uid=12(foo) euid=34(bar) gid=3(baz) \
#             egid=5(blat) groups=9(nine),2(two),1(one)

BEGIN {
    uid = PROCINFO["uid"]
    euid = PROCINFO["euid"]
    gid = PROCINFO["gid"]
    egid = PROCINFO["egid"]

    printf("uid=%d", uid)
    pw = getpwuid(uid)
    pr_first_field(pw)

    if (euid != uid) {
        printf(" euid=%d", euid)
        pw = getpwuid(euid)
        pr_first_field(pw)
    }

    printf(" gid=%d", gid)
    pw = getgrgid(gid)
    pr_first_field(pw)

    if (egid != gid) {
        printf(" egid=%d", egid)
        pw = getgrgid(egid)
        pr_first_field(pw)
    }

    for (i = 1; ("group" i) in PROCINFO; i++) {
        if (i == 1)
            printf(" groups=")
        group = PROCINFO["group" i]
        printf("%d", group)
        pw = getgrgid(group)
        pr_first_field(pw)
        if (("group" (i+1)) in PROCINFO)
            printf(",")
    }

    print ""
}

function pr_first_field(str,  a)
{
    if (str != "") {
        split(str, a, ":")
        printf("(%s)", a[1])
    }
}

Filemanager

Name Type Size Permission Actions
alarm.awk File 2.31 KB 0644
anagram.awk File 1.33 KB 0644
awksed.awk File 515 B 0644
cut.awk File 3.61 KB 0644
dupword.awk File 507 B 0644
egrep.awk File 1.91 KB 0644
extract.awk File 1.74 KB 0644
guide.awk File 165 B 0644
histsort.awk File 283 B 0644
id.awk File 1.22 KB 0644
igawk.sh File 3.11 KB 0644
indirectcall.awk File 952 B 0644
labels.awk File 1014 B 0644
split.awk File 1.17 KB 0644
tee.awk File 770 B 0644
testbits.awk File 729 B 0644
translate.awk File 1.15 KB 0644
uniq.awk File 2.64 KB 0644
wc.awk File 1.45 KB 0644
wordfreq.awk File 347 B 0644